
                     * PAG
                     **********************************************************
                     *  LINK - SYSTEM BOOTLOADER LINK UTILITY                 *
                     **********************************************************
                     * OPT PAG
                     *
                     * 'LINK' UTILITY COPYRIGHT (C), 1979 BY
                     *
                     *   TECHNICAL SYSTEMS CONSULTANTS, INC.
                     *   BOX 2570
                     *   WEST LAFAYETTE, INDIANA  47906
                     *   USA
                     
                     * BY FLD ON 25-11-2011 FOR VEGAS
                     * DISASSEMBLY BY DYNAMITE OF 1.LINK.CMD
                     
                     * STANDARD PRE-NAMED LABEL EQUATES
                     
               C840  SYSFCB  EQU    $C840
               CD03  WARMS   EQU    $CD03
               CD2D  GETFIL  EQU    $CD2D
               CD33  SETEXT  EQU    $CD33
               CD3F  RPTERR  EQU    $CD3F
               D403  FMSCLS  EQU    $D403
               D406  FMS     EQU    $D406
                     
                     
  C100                       ORG    $C100
                     
  C100 20   01       CMDADR  BRA    LINK1
  C102 01                    FCB    $01       VERSION NUMBER
  C103 8E   C840     LINK1   LDX    #SYSFCB   GET SYSTEM FCB ADRESS
  C106 BD   CD2D             JSR    GETFIL    GET FILE SPECIFICATION
  C109 25   40               BCS    LINK2     JUMP ON ERROR
  C10B 8E   C840             LDX    #SYSFCB   GET SYSTEM FCB ADRESS
  C10E 86   04               LDA    #4        CODE FOR .SYS EXTENSION
  C110 BD   CD33             JSR    SETEXT    SET THE SYS EXTENSION
  C113 8E   C840             LDX    #SYSFCB
  C116 86   01               LDA    #1        CODE FOR OPEN FOR READ 
  C118 A7   84               STA    0,X       STORE FUNCTION
  C11A BD   D406             JSR    FMS       CALL FMS
  C11D 26   30               BNE    LINK3     JUMP ON ERROR
  C11F 6F   88 1E            CLR    30,X      SET THE TRACK $00 FOR WRITING
  C122 86   01               LDA    #1
  C124 A7   88 1F            STA    31,X      SET THE SECTOR $01 FOR WRITING
  C127 86   09               LDA    #9        CODE FOR READ SINGLE SECTOR
  C129 A7   84               STA    0,X       STORE FUNCTION
  C12B BD   D406             JSR    FMS       CALL FMS
  C12E 26   1F               BNE    LINK3     JUMP ON ERROR
  C130 EC   88 11            LDD    17,X      LOAD THE STARTING ADRESS OF THE FILE
  C133 ED   88 45            STD    69,X      STORE IT IN POSITION 5 & 6
  C136 86   0A               LDA    #$0A      CODE FOR WRITE SINGLE SECTOR
  C138 A7   84               STA    0,X       STORE FUNCTION
  C13A BD   D406             JSR    FMS       CALL FMS
  C13D 27   13               BEQ    LINK4     ALL DONE 
  C13F A6   01               LDA    1,X       GET ERROR STATUS CODE
  C141 81   40               CMPA   #$40      IS IT $40 
  C143 26   0A               BNE    LINK3     IF NOT GOTO ERROR
  C145 C6   0B               LDB    #$0B      SET ERROR 11 WRITE PROTECT
  C147 E7   01               STB    1,X       STORE CODE
  C149 20   04               BRA    LINK3     GOTO ERROR
  C14B C6   15       LINK2   LDB    #$15      ILLEGAL FILE SPEC ERROR CODE
  C14D E7   01               STB    1,X
  C14F BD   CD3F     LINK3   JSR    RPTERR    REPORT ERROR
  C152 BD   D403     LINK4   JSR    FMSCLS
  C155 7E   CD03             JMP    WARMS     FINISHED
                     
                             END    CMDADR

0 ERROR(S) DETECTED

SYMBOL TABLE:

CMDADR C100   FMS    D406   FMSCLS D403   GETFIL CD2D   LINK1  C103   
LINK2  C14B   LINK3  C14F   LINK4  C152   RPTERR CD3F   SETEXT CD33   
SYSFCB C840   WARMS  CD03   




